actionscript3.0 相对运动小案例

 

分析:

上例中按键向右的话，小球向右边移动，按键向左的话，小球向左移动，当快移动到背景图的两端时候，小球还在移动，直到靠边。

其实当小球移动到舞台的中央过后，再向右移动的时候，背景图就同时开始在向左移动，直到小球移动到快要到背景图的另外一端，背景图才不移动。 从舞台一端开始，你移动小球到了舞台正中央的时候，你应该感觉到小球始终在正中央，此时的背景在向小球移动相反的方向移动。

你观看这个过程就像你观看一个人在扶手自动电梯上向电梯相反方向走步一样。电梯向上一台阶，人就向下一台阶。所以人始终还是在电梯原来那一阶，这个道理就和小球为什么始终在舞台中央一样，但电梯一直在向上运动。如果把人比作小球，电梯比作背景，那么背景就一直在向上运动，就会感觉背景里的小球没运动。 当然你也可以理解为，小球向下运动，而背景没运动。这个就看你选择什么作为参照物了。

程序中，背景图宽800像素，小球和背景分别用了两个视图容器来处理这种相对移动。

小球类：

Ball.as

package com.helloshp.view
{
    import flash.display.Sprite;

    public class Ball extends Sprite
    {
        public function Ball()
        {
            super();
            init();
        }

        private function init():void{
            this.graphics.beginFill(0xff0000);
            this.graphics.drawCircle(0,0,20);
            this.graphics.endFill();
        }
    }
}

背景类:

SceneView.as

package com.helloshp.view
{
    import flash.display.Sprite;

    public class SceneView extends Sprite
    {
        [Embed(source="assets/bg.jpg")]
        private var bg:Class;

        public function SceneView()
        {
            super();
            init();
        }

        private function init():void{
            addChild( new bg() );
        }
    }
}

主视图类：

MainView.as

package com.helloshp
{
    import com.helloshp.view.Ball;
    import com.helloshp.view.SceneView;

    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.KeyboardEvent;
    import flash.ui.Keyboard;

    public class MainView extends Sprite
    {
        private var ball:Ball;
        private var sv:SceneView;

        private var isStart:Boolean;
        private var speed:int;
        private const LIMIT_LEFT:int=0;    //背景图左边界
        private const LIMIT_RIGHT:int=800;//背景图右边界

        public function MainView()
        {
            super();


            if(stage!=null){
                init();
            }
            else{
                this.addEventListener(Event.ADDED_TO_STAGE,addedHandler)
            }

        }

        private function init():void{
            ball = new Ball();
            sv = new SceneView();
            addChild( sv );      //把背景试图放到舞台上
            sv.addChild(ball);//把小球放到背景试图里面，而不是放到舞台上
            ball.y = 200;

            stage.addEventListener(KeyboardEvent.KEY_DOWN,keyDownHandler);
            stage.addEventListener(KeyboardEvent.KEY_UP,kyUpHandler);
            addEventListener(Event.ENTER_FRAME,enterFrameHandler);
        }

        //键盘弹起就停止移动
        private function kyUpHandler(e:KeyboardEvent):void{
            isStart = false;
        }

        //键盘按下就开始移动
        private function keyDownHandler(e:KeyboardEvent):void{
            switch( e.keyCode ){
                case Keyboard.RIGHT:
                    isStart = true;
                    speed = 10;
                    break;
                case Keyboard.LEFT:
                    isStart = true;
                    speed = -10;
                    break;
                default:
                    speed = 0;
                    break;
            }
        }

        private function enterFrameHandler(e:Event):void{
            if( !isStart) return;

            ball.x += speed;//小球在X轴加速移动


            if(ball.x < LIMIT_LEFT)//如果小球的X坐标小于背景视图的左边界，就让小球一直停止在视图的左边界的位置
                ball.x = LIMIT_LEFT;
            else if( ball.x > LIMIT_RIGHT  )//如果小球的X坐标大于背景视图的右边界，就让小球一直停止在视图的右边界位置
                ball.x = LIMIT_RIGHT;


            if( ball.x < stage.stageWidth/2 ){//如果小球X坐标运动小于舞台一半，就让场景视图停止在左边界
                sv.x = LIMIT_LEFT;
            }
            else if( ball.x > LIMIT_RIGHT - stage.stageWidth/2 ){//如果小球X坐标运动到 大于 背景视图右边界减去舞台宽度一半，就让背景视图右边界移动到舞台的右边界
                sv.x = -LIMIT_RIGHT + stage.stageWidth;
            }
            else{//当小球运动到舞台的一半的时候，背景视图 就在舞台上向小球相反的方向运动，
                sv.x = -(ball.x - stage.stageWidth/2);
            }
        }

        private function addedHandler(e:Event):void{
            init();
        }
    }
}

 

源代码下载：https://files.cnblogs.com/bigbigdotnet/relativeMove.rar