The following program asks for a transaction code or a program name. If a transaction code is entered, its called program is used as the program name. With the program name, its package is retrieved, and all the Enhancements (Customer Exits) and classic BAdIs of this package are displayed.

It means this program is an help to find some Enhancements (customer exits) and BAdIs in the same package, but maybe they are not related to this transaction or program, and moreover, this transaction or program may call many Enhancements (customer exits) and BAdIs which will not be listed by this program. Instead, prefer Finding a BADI using Buffer trace - Transaction ST05 (Screenshots) or Find a BADI through SPRO.

REPORT Z_FIND_BADI .
TABLES : TSTC, TADIR, MODSAPT, MODACT, TRDIR, TFDIR, ENLFDIR, SXS_ATTRT, TSTCT.
DATA : JTAB LIKE TADIR OCCURS 0 WITH HEADER LINE.
DATA : FIELD1(30).
DATA : V_DEVCLASS LIKE TADIR-DEVCLASS.
DATA WA_TADIR TYPE TADIR.
 
PARAMETERS : P_TCODE LIKE TSTC-TCODE,
P_PGMNA LIKE TSTC-PGMNA .
 
START-OF-SELECTION.
IF NOT P_TCODE IS INITIAL.
  SELECT SINGLE * FROM TSTC WHERE TCODE EQ P_TCODE.
ELSEIF NOT P_PGMNA IS INITIAL.
  TSTC-PGMNA = P_PGMNA.
ENDIF.
IF SY-SUBRC EQ 0.
  SELECT SINGLE * FROM TADIR
        WHERE PGMID = 'R3TR'
          AND OBJECT = 'PROG'
          AND OBJ_NAME = TSTC-PGMNA.
  MOVE : TADIR-DEVCLASS TO V_DEVCLASS.
  IF SY-SUBRC NE 0.
    SELECT SINGLE * FROM TRDIR
          WHERE NAME = TSTC-PGMNA.
    IF TRDIR-SUBC EQ 'F'.
      SELECT SINGLE * FROM TFDIR
            WHERE PNAME = TSTC-PGMNA.
      SELECT SINGLE * FROM ENLFDIR
            WHERE FUNCNAME = TFDIR-FUNCNAME.
      SELECT SINGLE * FROM TADIR
            WHERE PGMID = 'R3TR'
              AND OBJECT = 'FUGR'
              AND OBJ_NAME EQ ENLFDIR-AREA.
      MOVE : TADIR-DEVCLASS TO V_DEVCLASS.
    ENDIF.
  ENDIF.
  SELECT * FROM TADIR INTO TABLE JTAB
        WHERE PGMID = 'R3TR'
          AND OBJECT IN ('SMOD', 'SXSD')
          AND DEVCLASS = V_DEVCLASS.
  SELECT SINGLE * FROM TSTCT
        WHERE SPRSL EQ SY-LANGU
          AND TCODE EQ P_TCODE.
  FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.
  WRITE:/(19) 'Transaction Code - ',
        20(20) P_TCODE,
        45(50) TSTCT-TTEXT.
  SKIP.
  IF NOT JTAB[] IS INITIAL.
    WRITE:/(105) SY-ULINE.
    FORMAT COLOR COL_HEADING INTENSIFIED ON.
* Sorting the internal Table
    SORT JTAB BY OBJECT.
    DATA : WF_TXT(60) TYPE C,
          WF_SMOD TYPE I ,
          WF_BADI TYPE I ,
          WF_OBJECT2(30) TYPE C.
    CLEAR : WF_SMOD, WF_BADI , WF_OBJECT2.
* Get the total SMOD.
    LOOP AT JTAB INTO WA_TADIR.
      AT FIRST.
        FORMAT COLOR COL_HEADING INTENSIFIED ON.
        WRITE:/1 SY-VLINE,
              2 'Enhancement/ Business Add-in',
              41 SY-VLINE ,
              42 'Description',
              105 SY-VLINE.
        WRITE:/(105) SY-ULINE.
      ENDAT.
 
      CLEAR WF_TXT.
 
      AT NEW OBJECT.
        IF WA_TADIR-OBJECT = 'SMOD'.
          WF_OBJECT2 = 'Enhancement' .
        ELSEIF WA_TADIR-OBJECT = 'SXSD'.
          WF_OBJECT2 = ' Business Add-in'.
        ENDIF.
        FORMAT COLOR COL_GROUP INTENSIFIED ON.
        WRITE:/1 SY-VLINE,
              2 WF_OBJECT2,
              105 SY-VLINE.
      ENDAT.
 
      CASE WA_TADIR-OBJECT.
      WHEN 'SMOD'.
        WF_SMOD = WF_SMOD + 1.
        SELECT SINGLE MODTEXT INTO WF_TXT
              FROM MODSAPT
              WHERE SPRSL = SY-LANGU
                AND NAME = WA_TADIR-OBJ_NAME.
        FORMAT COLOR COL_NORMAL INTENSIFIED OFF.
      WHEN 'SXSD'.
* For BADis
        WF_BADI = WF_BADI + 1 .
        SELECT SINGLE TEXT INTO WF_TXT
              FROM SXS_ATTRT
              WHERE SPRSL = SY-LANGU
                AND EXIT_NAME = WA_TADIR-OBJ_NAME.
        FORMAT COLOR COL_NORMAL INTENSIFIED ON.
      ENDCASE.
      WRITE:/1 SY-VLINE,
            2 WA_TADIR-OBJ_NAME HOTSPOT ON,
            41 SY-VLINE ,
            42 WF_TXT,
            105 SY-VLINE.
 
      AT END OF OBJECT.
        WRITE : /(105) SY-ULINE.
      ENDAT.
    ENDLOOP.
    WRITE:/(105) SY-ULINE.
    SKIP.
    FORMAT COLOR COL_TOTAL INTENSIFIED ON.
    WRITE:/ 'No.of Exits:' , WF_SMOD.
    WRITE:/ 'No.of BADis:' , WF_BADI.
  ELSE.
    FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
    WRITE:/(105) 'No userexits or BADis exist'.
  ENDIF.
ELSE.
  FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
  WRITE:/(105) 'Transaction does not exist'.
ENDIF.
 
AT LINE-SELECTION.
  DATA : WF_OBJECT TYPE TADIR-OBJECT.
  CLEAR WF_OBJECT.
  GET CURSOR FIELD FIELD1.
  CHECK FIELD1(8) EQ 'WA_TADIR'.
  READ TABLE JTAB WITH KEY OBJ_NAME = SY-LISEL+1(20).
  MOVE JTAB-OBJECT TO WF_OBJECT.
  CASE WF_OBJECT.
    WHEN 'SMOD'.
      SET PARAMETER ID 'MON' FIELD SY-LISEL+1(10).
      CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.
    WHEN 'SXSD'.
      SET PARAMETER ID 'EXN' FIELD SY-LISEL+1(20).
      CALL TRANSACTION 'SE18' AND SKIP FIRST SCREEN.
  ENDCASE.

[转帖]SAP BADI应用

http://space.itpub.net/10500555/viewspace-616097

上一篇 / 下一篇 2009-10-08 10:40:34 / 个人分类：SAP學習

查看( 1798 ) / 评论( 2 ) / 评分( 3 / 0 )

1.定义BADI
1) T-Code: SE18 Business Add-In Define.

2) 输入要创建的BADI的名字，点击"Create"。

3) 输入BADI的描述性文本，在"Interface"选项卡上输入接口的名字，也可以采用SAP建议的接口的名字。同时，BADI类也会被创建。

例如：对于BADI "ZTEST"，SAP会建议"ZIF_EX_TEST"作为接口的名字，"ZCL_EX_TEST"作为类的名字。

4) 保存BADI。

5) 双击接口的名字，会跳转到Class Builder界面，在这里你可以定义接口的方法。

6) 保存并激活接口。

2.实现BADI
         1) T-Code: SE19     Business Add-In Implementation
         2) 输入BADI实现的名字，点击"Create"。
         3) 输入BADI定义的名字。
         4) 输入实现的描述性文本，在"Interface"选项卡上输入实现类的名字。可以采用SAP建议的名字。

例如："ZIMPTEST"，SAP会建议"ZCL_IM_IMPTEST"。

5) 保存实现。

6) 双击某一方法名会跳转到Class Builder界面，在这里你可以添加代码来重定义接口方法。

7) 激活实现。

3. 程序中调用BADI

1) 先用类型参照引用出要调用的BADI
2) 实例化BADI
3) 实例化后就可以任意调用BADI 中的方法了。

REPORT ZZW_BAPI_01 .

data exit type ref to ZIF_EX_ZW_BD_TEST.

call method cl_exithandler=>get_instance
changing
instance = exit.

call method exit->Z_ZW_01.

==》
badi 小记
BADI作为SAP的第三代用户出口，他的应用也越来越广泛，但如何找到合适的badi是许多abap程序员的困惑。我这里就介绍一下我个人的应用的经验，供大家参考。

1、badi对象的信息存储在SXS_INTER, SXC_EXIT, SXC_CLASS 和SXC_ATTR 这四个表中（参见SECE包）；

2、sap程序都会调用cl_exithandler=>get_instance来判断对象是否存在，并返回实例；其实get_instance就是对上述几个表和他们的视图（V_EXT_IMP 和 V_EXT_ACT）进行查询和搜索。

3、基于这个机理，我查用ST05来监控一个TCODE来跟踪，然后选择查找有关上述几个表和视图的操作，就可获得相关BADI。

4、se18 查找接口，se19 实现接口就可以实现用户增强。
示例：用LE_SHP_DELIVERY_PROC控制跨月Cancel

METHOD IF_EX_LE_SHP_DELIVERY_PROC~CHANGE_DELIVERY_HEADER .
data : thismonth(2) type c.
data : wa_likp type line of SHP_LIKP_T.
data : wa_log type line of SHP_BADI_ERROR_LOG_T.
clear ct_log[],thismonth.
thismonth = sy-datum+4(2). "----->这一个月的月份
loop at it_xlikp into wa_likp.
check IS_V50AGL-WARENAUSG_STORNO ='X'."--->代表作GI cancel
if wa_likp-WADAT_IST+4(2) < thismonth.
wa_log-VBELN = cs_likp-vbeln.
wa_log-MSGTY = 'E'. "错误信息
wa_log-MSGID = 'ZDN_ERROR'. "这一个class要自己建
wa_log-MSGNO = '001'.
append wa_log to ct_log. "Error log写入
endif.
endloop.
ENDMETHOD.

VerySky

工作记录，学习积累，经验分享，好文收藏……

如何从SAP中查找BADI

如何通过Tcode查找Badi或者用户出口

查找BADi的六种方法

Code To Find BAdi

[转帖]SAP BADI应用

公告