POJ1734 - Sightseeing trip

Description
There is a travel agency in Adelton town on Zanzibar island. It has decided to offer its clients, besides many other attractions, sightseeing the town. To earn as much as possible from this attraction, the agency has accepted a shrewd decision: it is necessary to find the shortest route which begins and ends at the same place. Your task is to write a program which finds such a route.

In the town there are N crossing points numbered from 1 to N and M two-way roads numbered from 1 to M. Two crossing points can be connected by multiple roads, but no road connects a crossing point with itself. Each sightseeing route is a sequence of road numbers y_1, ..., y_k, k>2. The road y_i (1<=i<=k-1) connects crossing points x_i and x_{i+1}, the road y_k connects crossing points x_k and x_1. All the numbers x_1,...,x_k should be different.The length of the sightseeing route is the sum of the lengths of all roads on the sightseeing route, i.e. L(y_1)+L(y_2)+...+L(y_k) where L(y_i) is the length of the road y_i (1<=i<=k). Your program has to find such a sightseeing route, the length of which is minimal, or to specify that it is not possible,because there is no sightseeing route in the town.

Input
The first line of input contains two positive integers: the number of crossing points N<=100 and the number of roads M<=10000. Each of the next M lines describes one road. It contains 3 positive integers: the number of its first crossing point, the number of the second one, and the length of the road (a positive integer less than 500).

Output
There is only one line in output. It contains either a string 'No solution.' in case there isn't any sightseeing route, or it contains the numbers of all crossing points on the shortest sightseeing route in the order how to pass them (i.e. the numbers x_1 to x_k from our definition of a sightseeing route), separated by single spaces. If there are multiple sightseeing routes of the minimal length, you can output any one of them.

Sample Input

5 7
1 4 1
1 3 300
3 1 10
1 2 16
2 3 100
2 5 15
5 3 20

Sample Output

1 3 5 2

 

题目大意：给你一个无向图，要你求最小环，并输出路径

用floyd求最短路时顺便求最小环

floyd主程序

for k:=1 to n do
  for i:=1 to n do
    for j:=1 to n do
      f[i,j]:=min(f[i,j],f[i,k]+f[k,j]);

然后我们可以在里面加一点东西

for k:=1 to n do
  begin
    for i:=1 to k-1 do
      for j:=1 to i-1 do
        minc:=min(minc,f[i,j]+g[i,k]+g[k,j]);
    for i:=1 to n do
      for j:=1 to n do
        f[i,j]:=min(f[i,j],f[i,k]+f[k,j]);
  end;

g存的是原图信息

因为当k枚举到a时，最短路除了两端点外，都只能经过编号小于a的点

在最小环中，一定有一个编号最大的点，而且只有一个（废话......）

设这个点编号为b，当k枚举到b时，i，j枚举到b在环上相邻的两点时，f[i,j]存的是i，j之间不通过大于b的点的最短路，这当然就是最小环了

const
    maxn=102;
var
    f,g,p:array[0..maxn,0..maxn]of longint;
    path:array[0..maxn]of longint;
    ans,tot,n,m:longint;

procedure init;
var
    i,x,y,z:longint;
begin
    read(n,m);
    fillchar(g,sizeof(g),1);
    for i:=1 to m do
      begin
        read(x,y,z);
        if g[x,y]>z then
        begin
          g[x,y]:=z;
          g[y,x]:=z;
        end;
      end;
    f:=g;
end;

procedure get(i,j:longint);
begin
    if p[i,j]<>0 then
    begin
      get(i,p[i,j]);
      get(p[i,j],j);
      exit;
    end;
    inc(tot);
    path[tot]:=j;
end;

procedure work;
var
    i,j,k:longint;
begin
    ans:=g[0,0];
    for k:=1 to n do
      begin
        for i:=1 to k-1 do
          for j:=1 to i-1 do
            if ans>f[i,j]+g[i,k]+g[k,j] then
            begin
              ans:=f[i,j]+g[i,k]+g[k,j];
              tot:=0;
              inc(tot);
              path[tot]:=i;
              get(i,j);
              inc(tot);
              path[tot]:=k;
            end;
        for i:=1 to n do
          for j:=1 to n do
            if f[i,j]>f[i,k]+f[k,j] then
            begin
              p[i,j]:=k;
              f[i,j]:=f[i,k]+f[k,j];
            end;
      end;
    if ans=g[0,0] then write('No solution.')
    else
      for i:=1 to tot do
        write(path[i],' ');
end;

begin
    init;
    work;
end.