noip2005 过河 解题报告

过河 解题报告

【问题描述】

     在河上有一座独木桥，一只青蛙想沿着独木桥从河的一侧跳到另一侧。在桥上有一些石子，青蛙很讨厌踩在这些石子上。由于桥的长度和青蛙一次跳过的距离都是正整数，我们可以把独木桥上青蛙可能到达的点看成数轴上的一串整点：0，1，……，L（其中L是桥的长度）。坐标为0的点表示桥的起点，坐标为L的点表示桥的终点。青蛙从桥的起点开始，不停的向终点方向跳跃。一次跳跃的距离是S到T之间的任意正整数（包括S,T）。当青蛙跳到或跳过坐标为L的点时，就算青蛙已经跳出了独木桥。

          题目给出独木桥的长度L，青蛙跳跃的距离范围S,T，桥上石子的位置。你的任务是确定青蛙要想过河，最少需要踩到的石子数。其中L<=10^9，石子数m<=1000,1<=s<=t<=10;

【分析】

    这道题直接搜索显然是不可行的，必然TLE，考虑动态规划：

     opt[n]:=min{opt[n-i]+rock[n]}(s<=i<=t)  //rock[n]表示当前位置有没有石子。

    时间复杂度是O（n），对于小于等于10^9的L显然是不可行的，于是我们可以尝试进行优化。如此大的长度，而石子数却只有1000，说明中间必然有很大的空白，可以将其压缩。

    我们先看一个方程。px+（p+1)y=Q（采用跳跃距离p和p+1时跳至位置Q）因为p和p+1相隔1，所以当Q>=p(p-1)时该方程必然有整数解（可以用同余的思想证明：p mod （p+1）=-1；设Q mod （p+1）=-k (k>0) ,则当x=k时，（p+1)y=Q-px，mod （p+1）必然为0，此时y为非负整数。命题得证）。这就意味着如果跳跃距离如果不小于s（s-1），且s不等于t，那么必然可以跳到，这样便可以实现压缩，以石子为状态动态规划。

    好了，切入正题，说怎么做吧。我们用b[i]为能否用s到t的一次跳跃距离跳至i远的标志（当s<=i<=th或i=0时为真)，c[v]为青蛙能否跳到相对距离为v远的标志（v≤90）。

      则当v<0时，c[v]:=0;

      当v>=s(s-1)时，c[v]:=true;

      当1<=s<=s(s-1)时，c[v]:=b[v];

    (s=t时需特殊处理）

    

    a[i,j]为青蛙跳至x[i]左方相对距离为j的位置时所经过的最少石子总数。若j=0，说明青蛙踩到了桥上的第i个石子。初始时，a[i,j]=n+1（0≤i≤n，0≤j≤t-1）。 第1种情况：x[i]-j位置位于x[i-1]的左方，即x[i]-j≤x[i-1]显然，跳至x[i]-j位置经过的最少石子总数为a[i-1,j-x[i]+x[i-1]]。第2种情况：x[i]-j位置位于x[i-1]的右方，即x[i]-j>x[i-1]。显然，如果青蛙能够由x[i-1]-v位置跳至x[i]-j位置（can(x[i]-j-x[i-1]+v)=true），则跳至x[i]-j位置经过的石子总数为a[i-1,v]或者为a[i-1,v]+1（j=0时，即踩到了桥上的第i个石子）。但究竟v多大时，才能使得最少石子数最少呢，我们无法预知，只能在0‥t-1的范围内一一枚举v，从中找出经过的最少石子数。 最后，我们枚举青蛙跳出独木桥前的最后一个起跳位置x[n]-i(0≤i≤t-1），从中计算出青蛙过河最少需要踩到的石子数。 

     至于s=t的情况是不能用这种方法处理的，因此要特殊处理，模拟一遍就可以了。

【代码】

     

var i,j,n,m,k,l,v:longint;
    x:array[0..100]of longint;
    a:array[0..100,0..100]of longint;
    b:array[0..100]of boolean;
    s,t,len:longint;
function can(x:longint):boolean;
begin
  if x<0 then exit(false);
  if x>=s*(s-1) then exit(true) else exit(b[x]);
end;
begin
  assign(input,'river.in');reset(input);
  assign(output,'river.out');rewrite(output);
  readln(len);readln(s,t,n);
  for i:=1 to n do read(x[i]);
  for i:=1 to n do
   for j:=i+1 to n do
    if x[i]>x[j] then
    begin
     k:=x[i];x[i]:=x[j];x[j]:=k;
    end;
  while x[n]>len do dec(n);
  x[0]:=0;
  fillchar(b,sizeof(b),false);
  b[0]:=true;
  for i:=s to 90 do
   for j:=s to t do
    b[i]:=b[i]or b[i-j];

  if s=t then
  begin
   k:=0;
   for i:=1 to n do
    if x[i]mod s=0 then inc(k);
   write(K);
   close(input);close(output);
   halt;
  end;

  fillchar(a,sizeof(a),63);
  a[0,0]:=0;
  for i:=1 to n do
   for j:=0 to t-1 do
   begin
    if x[i]-j<=x[i-1] then
    begin
     if a[i,j]>a[i-1,j-(x[i]-x[i-1])] then
      a[i,j]:=a[i-1,j-(x[i]-x[i-1])];
    end else
    begin
     for v:=0 to t-1 do
      if (can(x[i]-j-x[i-1]+v))and(a[i,j]>a[i-1,v]) then
       a[i,j]:=a[i-1,v];
     if j=0 then inc(a[i,j]);
    end;
   end;
  k:=maxlongint;
  for i:=0 to t-1 do if a[n,i]<k then k:=a[n,i];
  writeln(k);
  close(input);close(output);
end.